ASSIGN, PRINT="DCO.print.txt"
  OPTION, -ECHO, DOUBLE, VERIFY
  SETPLOT, XSIZE=25.4, YSIZE=20.32
  SETPLOT, LWIDTH=5, LSCALE=1.5, SSCALE=1.5, RSCALE=1.5  
                   
! ==============================================================================
! Load XSIF file
! ------------------------------------------------------------------------------

  CALL, FILENAME="kvals.72deg.xsif"
! CALL, FILENAME="kvals.90deg.xsif"
! CALL, FILENAME="kvals.108deg.xsif"

  CALL, FILENAME="DCO2.xsif"

! ==============================================================================
! SUBROUTINEs
! ------------------------------------------------------------------------------

MATCHARC: SUBROUTINE

  USE, ARC
  CELL
  
    VARY, K1.QARCF, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QARCD, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, MUX=ARCMUX
    CONSTRAINT, #E, MUY=ARCMUY

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE


! ------------------------------------------------------------------------------

MATCHDSP: SUBROUTINE

  USE, DSP
  MATCH, LINE=ARC
  
    VARY, K1.QDSP0, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QDSP1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QDSP2, STEP=1E-6, LOWER=-0.8, UPPER=+0.8
    VARY, K1.QDSP3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, QDSP3[1], BETY=BETYQDSP3
    CONSTRAINT, BDSP2[1], DX=0, DPX=0
    CONSTRAINT, QDSP4[1], BETY=BETYQDSP4

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

  USE, DSP
  MATCH, LINE=ARC
  
    VARY, K1.QDSP4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QDSP5, STEP=1E-6, LOWER=-0.7, UPPER=+1.2
    VARY, K1.QDSP6, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QDSP7, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, LINE=PHT

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHPHT: SUBROUTINE

  USE, PHT
  CELL
  
    VARY, K1.QPHT1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QPHT2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QPHT3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QPHT4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QPHT5, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QPHT6, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, BETX=39.690, ALFX=-2.107, MUX=0.667+PHTDMX
    CONSTRAINT, #E, BETY= 9.306, ALFY= 0.525, MUY=0.667+PHTDMY

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHCCH: SUBROUTINE

  USE, CCH
  CELL
  
    VARY, K1.QCCH1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QCCH2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, BETX=40
    CONSTRAINT, #E, BETY=16

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHINJ: SUBROUTINE

  USE, IJ0
  CELL
  
    VARY, K1.QINJ1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QINJ2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, DINJ3[1], BETX=70.972
    CONSTRAINT, #E, MUX=0.25

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHRFC: SUBROUTINE

  USE, RFC
  CELL
  
    VARY, K1.QRFC1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QRFC2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, MUX=0.2
    CONSTRAINT, #E, MUY=0.2

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHDLG: SUBROUTINE

  USE, DLG
  CELL
  
    VARY, K1.QDLG1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QDLG2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, BDLG2[1], DX=0, DPX=0

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHMPC: SUBROUTINE

  USE, MPC
  MATCH, LINE=PHT
  
    VARY, K1.QMPC1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMPC2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMPC3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMPC4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, LINE=CCH

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHMCI: SUBROUTINE

  USE, MCI
  MATCH, LINE=CCH
  
    VARY, K1.QMCI1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMCI2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMCI3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMCI4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, LINE=INJ

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHMIR: SUBROUTINE

  USE, MIR
  MATCH, LINE=INJ
  
    VARY, K1.QMIR1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMIR2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMIR3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMIR4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, LINE=RFC

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHMRD: SUBROUTINE

  USE, MRD
  MATCH, LINE=RFC
  
    VARY, K1.QMRD1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMRD2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMRD3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMRD4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, LINE=DLG

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHMDW: SUBROUTINE

  USE, MDW
  MATCH, LINE=DLG
  
    VARY, K1.QMDW1, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMDW2, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMDW3, STEP=1E-6, LOWER=-0.7, UPPER=+0.7
    VARY, K1.QMDW4, STEP=1E-6, LOWER=-0.7, UPPER=+0.7

    CONSTRAINT, #E, LINE=WGC

    SIMPLEX, CALLS=1000
    MIGRAD,  CALLS=1000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

MATCHPSD: SUBROUTINE

  USE, PSD
  MATCH, LINE=WGC
  
    VARY, K1.QPSD0, STEP=1E-6, LOWER=-0.9, UPPER=+0.9
    VARY, K1.QPSD1, STEP=1E-6, LOWER=-0.9, UPPER=+0.9
    VARY, K1.QPSD2, STEP=1E-6, LOWER=-0.9, UPPER=+0.9
    VARY, K1.QPSD3, STEP=1E-6, LOWER=-0.9, UPPER=+0.9

    VARY, K1.QPSD4, STEP=1E-6, LOWER=-0.9, UPPER=+0.9
    VARY, K1.QPSD5, STEP=1E-6, LOWER=-0.9, UPPER=+0.9
    VARY, K1.QPSD6, STEP=1E-6, LOWER=-0.9, UPPER=+0.9
    VARY, K1.QPSD7, STEP=1E-6, LOWER=-0.9, UPPER=+0.9

    CONSTRAINT, QPSD3[1], BETY=38
    CONSTRAINT, QPSD5[1], BETX=BETXQPSD5
    CONSTRAINT, QPSD6[1], BETY=40
    CONSTRAINT, #E, LINE=ARC2

    SIMPLEX, CALLS=10000
    MIGRAD,  CALLS=10000

  ENDMATCH

ENDSUBROUTINE

! ------------------------------------------------------------------------------

TUNECHROMATICITY: SUBROUTINE

  USE, RING
  HARMON

    HVARY, K2.SARC1, STEP=1E-6, LOWER=   0.0, UPPER=+100.0
    HVARY, K2.SARC2, STEP=1E-6, LOWER=-100.0, UPPER=   0.0

    HTUNE

  ENDHARM

ENDSUBROUTINE


! ==============================================================================
! COMMANDs
! ------------------------------------------------------------------------------

  RF_ON  := 0
  SXT_ON := 1

! ------------------------------------------------------------------------------
! Matching: note that the periodic cells are matched first
! ------------------------------------------------------------------------------

COMMENT

  MATCHARC
  MATCHPHT
  MATCHCCH
  MATCHINJ
  MATCHRFC
  MATCHDLG

  MATCHDSP
  MATCHMPC
  MATCHMCI
  MATCHMIR
  MATCHMRD
  MATCHMDW
  MATCHPSD

  TUNECHROMATICITY

ENDCOMMENT

  VALUE, K1.QARCF
  VALUE, K1.QARCD

  VALUE, K2.SARC1
  VALUE, K2.SARC2
  
  VALUE, K1.QDSP0
  VALUE, K1.QDSP1
  VALUE, K1.QDSP2
  VALUE, K1.QDSP3
  VALUE, K1.QDSP4
  VALUE, K1.QDSP5
  VALUE, K1.QDSP6
  VALUE, K1.QDSP7

  VALUE, K1.QPHT1
  VALUE, K1.QPHT2
  VALUE, K1.QPHT3
  VALUE, K1.QPHT4
  VALUE, K1.QPHT5
  VALUE, K1.QPHT6

  VALUE, K1.QMPC1
  VALUE, K1.QMPC2
  VALUE, K1.QMPC3
  VALUE, K1.QMPC4

  VALUE, K1.QCCH1
  VALUE, K1.QCCH2
  
  VALUE, K1.QMCI1
  VALUE, K1.QMCI2
  VALUE, K1.QMCI3
  VALUE, K1.QMCI4

  VALUE, K1.QINJ1
  VALUE, K1.QINJ2

  VALUE, K1.QMIR1
  VALUE, K1.QMIR2
  VALUE, K1.QMIR3
  VALUE, K1.QMIR4

  VALUE, K1.QRFC1
  VALUE, K1.QRFC2
  
  VALUE, K1.QMRD1
  VALUE, K1.QMRD2
  VALUE, K1.QMRD3
  VALUE, K1.QMRD4

  VALUE, K1.QDLG1
  VALUE, K1.QDLG2
  
  VALUE, K1.QMDW1
  VALUE, K1.QMDW2
  VALUE, K1.QMDW3
  VALUE, K1.QMDW4

  VALUE, K1.QPSD0
  VALUE, K1.QPSD1
  VALUE, K1.QPSD2
  VALUE, K1.QPSD3
  VALUE, K1.QPSD4
  VALUE, K1.QPSD5
  VALUE, K1.QPSD6
  VALUE, K1.QPSD7


! ------------------------------------------------------------------------------
! Output the lattice functions
! ------------------------------------------------------------------------------

  USE, RNGI
  TWISS, SAVE
  SURVEY, TAPE="DCO.survey.txt"

  SELECT, OPTICS, CLEAR
  SELECT, OPTICS, #S/#E

  OPTICS, COLUMNS= NAME, S, L,               &
                   BETX, ALFX, MUX, DX, DPX, &
                   BETY, ALFY, MUY,          &
                   K0L, E1, E2, K1L, K2L,    &
                   FILENAME= "DCO.lfunctions.txt"

  OPTICS, COLUMNS= NAME, KEYWORD, S, L,                    &
                   K0L, E1, E2, K1L, KS1L, K2L, K3L, TILT, &
                   FILENAME= "DCO.lattice.txt"


! ------------------------------------------------------------------------------
! Produce some plots
! ------------------------------------------------------------------------------

  USE, ARC
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Arc Cell"

  USE, DSP
  TWISS, LINE=ARC, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Dispersion Suppressor"
        
  USE, PHT
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Phase Trombone"
        
  USE, MPC
  TWISS, LINE=PHT, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Matching Trombone to Chicane"
        
  USE, CCH
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Circumference Chicane"

  USE, MCI
  TWISS, LINE=CCH, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0, VMAX=100                                    &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Matching Chicane to Injection"
        
  USE, INJ
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0, VMAX=100                                   &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Injection"

  USE, MIR
  TWISS, LINE=IJ0, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0, VMAX=100                                    &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Matching Injection to RF"
        
  USE, RFC
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="RF Cavities"
        
  USE, MRD
  TWISS, LINE=RFC, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,            &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Matching RF to Dogleg"

  USE, DLG
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        VMIN=0,-1, VMAX=50,1                               &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Dogleg"
        
  USE, MDW
  TWISS, LINE=DLG, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY,             &
        VMIN=0, VMAX=50                                     &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Matching Dogleg to Wiggler"
        
  USE, WGC
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        VMIN=0, VMAX=50                                    &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Wiggler"
        
  USE, PSD
  TWISS, LINE=WGC, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        VMIN=0,-1, VMAX=50,1                                    &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Reverse Dispersion Suppressor"

  USE, STRT
  PRINT, MRK1
  PRINT, MRK2
  PRINT, MRK3
  PRINT, MRK4
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        HMIN=0,    HMAX=1300,                              &
        VMIN=0,-1, VMAX=100,1                              &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Straight"

  USE, HRNGI
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        HMIN=0,    HMAX=3240,                              &
        VMIN=0,-1, VMAX=100,1                              &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Half Ring"

  USE, RNGI
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        HMIN=0,    HMAX=6480,                              &
        VMIN=0,-1, VMAX=100,1                              &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Half Ring"

  USE, RING
  TWISS, SAVE
  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, &
        HMIN=0,    HMAX=6480,                              &
        VMIN=0,-1, VMAX=100,1                              &
        STYLE=1, COLOUR=100, SPLINE=.T., TITLE="Ring"


! ------------------------------------------------------------------------------
! Calculate the beam parameters
! ------------------------------------------------------------------------------

  ASSIGN, PRINT="DCO.BMPM.txt"

  USE, RING
  SELECT, TWISS, MRK1
  SELECT, TWISS, MRK2
  SELECT, TWISS, MRK3
  SELECT, TWISS, MRK4
  TWISS, SAVE

  RF_ON  := 0
  SXT_ON := 0
  TWISS, SAVE

  RF_ON  := 0
  SXT_ON := 1
  TWISS, SAVE

  RF_ON  := 1
  SXT_ON := 1
  USE, RNGI
  TWISS, SAVE
  BEAM, PARTICLE=POSITRON, ENERGY=E0, RADIATE
  BMPM

STOP

! ------------------------------------------------------------------------------
! Tracking: make phase space portraits
! ------------------------------------------------------------------------------

  ASSIGN, PRINT="DCO.TRACK.txt"

  RF_ON  := 0
  SXT_ON := 1
  BEAM, PARTICLE=POSITRON, ENERGY=E0, RADIATE=FALSE
  USE, HRNGI


  TRACK

    X0 := 1

    DO, TIMES=50

        START, X     = X0*0.001, &
               PX    = 0,  &
               Y     = 0.0005,   &
               PY    = 0,  &
               T     = 0,  &
               DELTAP= 0.0

        SET, X0, X0 + 1

    ENDDO

    OBSERVE, PLACE=#E, TABLE=TRACKTABLE
    RUN, METHOD=TRANSPORT, TABLE=TRACKTABLE, TURNS=100

    PLOT, TABLE=TRACKTABLE, HAXIS=X, VAXIS=PX, SYMBOL=3, MULTIPLE, &
          HMIN=-0.060, HMAX=+0.060, VMIN=-0.0030, VMAX=+0.0030

  ENDTRACK


  TRACK

    Y0 := 1

    DO, TIMES=80

        START, X     = 0,  &
               PX    = 0,  &
               Y     = Y0*0.001,  &
               PY    = 0,  &
               T     = 0,  &
               DELTAP= 0.0

        SET, Y0, Y0 + 1

    ENDDO

    OBSERVE, PLACE=#E, TABLE=TRACKTABLE
    RUN, METHOD=TRANSPORT, TABLE=TRACKTABLE, TURNS=100

    PLOT, TABLE=TRACKTABLE, HAXIS=X, VAXIS=PX, SYMBOL=3, MULTIPLE, &
          HMIN=-0.060, HMAX=+0.060, VMIN=-0.0030, VMAX=+0.0030

    PLOT, TABLE=TRACKTABLE, HAXIS=Y, VAXIS=PY, SYMBOL=3, MULTIPLE, &
          HMIN=-0.060, HMAX=+0.060, VMIN=-0.0010, VMAX=+0.0010

  ENDTRACK


STOP


! ------------------------------------------------------------------------------
! Dynamic Aperture: dp = 0.0
! ------------------------------------------------------------------------------

  RF_ON := 0
  BEAM, PARTICLE=POSITRON, ENERGY=E0, RADIATE=FALSE

  nsigma  = 0.17
  deltang = 0.5*pi/20.0
  angolo  = 0.0001
  dp      = 0.0

  DO, TIMES=41

    SET, fxval, nsigma*cos(angolo)
    SET, fyval, nsigma*sin(angolo)

    DYNAPSTART, X=fxval, Y=fyval, DELTAP=dp,               &  
                TURNS=200, STEP=0.025, ORBIT, DAMP=FALSE,  &
                METHOD=TRANSPORT

    DYNAP

    SET, dynapx, fxval*DYNAPFRAC
    SET, dynapy, fyval*DYNAPFRAC

    PUSH, angolo, fxval, fyval,                      &
          dynapx,  dynapy,                           &
          xdynapx, ydynapy,                          &
          DYNAPFRAC    

    SET, angolo, angolo + deltang

  ENDDO

  ENDPUSH, SAVE

  PLOT, TABLE=SPECIAL,                               &
        TITLE="Dynamic aperture for dp=0.0",         &      
        HAXIS=dynapx, HMIN=-0.10, HMAX=0.10,         &
        VAXIS=dynapy, VMIN= 0.00, VMAX=0.20

! ------------------------------------------------------------------------------
! Dynamic Aperture: dp = 0.005
! ------------------------------------------------------------------------------

  nsigma  = 0.17
  deltang = 0.5*pi/20.0
  angolo  = 0.0001
  dp      = 0.005

  DO, TIMES=41

    SET, fxval, nsigma*cos(angolo)
    SET, fyval, nsigma*sin(angolo)

    DYNAPSTART, X=fxval, Y=fyval, DELTAP=dp,               &  
                TURNS=200, STEP=0.025, ORBIT, DAMP=FALSE,  &
                METHOD=TRANSPORT

    DYNAP

    SET, dynapx, fxval*DYNAPFRAC
    SET, dynapy, fyval*DYNAPFRAC

    PUSH, angolo, fxval, fyval,                      &
          dynapx,  dynapy,                           &
          xdynapx, ydynapy,                          &
          DYNAPFRAC    

    SET, angolo, angolo + deltang

  ENDDO

  ENDPUSH, SAVE

  PLOT, TABLE=SPECIAL,                               &
        TITLE="Dynamic aperture for dp=0.005",       &      
        HAXIS=dynapx, HMIN=-0.10, HMAX=0.10,         &
        VAXIS=dynapy, VMIN= 0.00, VMAX=0.20

! ------------------------------------------------------------------------------
! Dynamic Aperture: dp =-0.005
! ------------------------------------------------------------------------------

  nsigma  = 0.17
  deltang = 0.5*pi/20.0
  angolo  = 0.0001
  dp      =-0.005

  DO, TIMES=41

    SET, fxval, nsigma*cos(angolo)
    SET, fyval, nsigma*sin(angolo)

    DYNAPSTART, X=fxval, Y=fyval, DELTAP=dp,               &  
                TURNS=200, STEP=0.025, ORBIT, DAMP=FALSE,  &
                METHOD=TRANSPORT

    DYNAP

    SET, dynapx, fxval*DYNAPFRAC
    SET, dynapy, fyval*DYNAPFRAC

    PUSH, angolo, fxval, fyval,                      &
          dynapx,  dynapy,                           &
          xdynapx, ydynapy,                          &
          DYNAPFRAC    

    SET, angolo, angolo + deltang

  ENDDO

  ENDPUSH, SAVE

  PLOT, TABLE=SPECIAL,                               &
        TITLE="Dynamic aperture for dp=-0.005",      &      
        HAXIS=dynapx, HMIN=-0.10, HMAX=0.10,         &
        VAXIS=dynapy, VMIN= 0.00, VMAX=0.20