E0      := 5.0           ! nominal beam energy (GeV)
  

  BLENGTH := 2.00          ! length of standard bending magnet
  QLENGTH := 0.20         ! half length of standard quadrupole
  SLENGTH := 0.25          ! length of standard sextupole

  ANGARCB := TWOPI/340     ! angle of arc bending magnet 

 ! B0=ANGARCB*E0/0.2997/BLENGTH
  !VALUE, B0

 !**** Arc ********
 
 BARC:    SBEND, L=BLENGTH, ANGLE=ANGARCB, E1=ANGARCB/2, E2=ANGARCB/2
 
 QARCF:   QUADRUPOLE, L=QLENGTH, K1=K1.QARCF
 QARCD:   QUADRUPOLE, L=QLENGTH, K1=K1.QARCD
 
 SARCF: SEXTUPOLE, L=SLENGTH, K2=K2.SARCF
 SARCD: SEXTUPOLE, L=SLENGTH, K2=K2.SARCD
 SARCF2: SEXTUPOLE, L=SLENGTH, K2=K2.SARCF2
 SARCD2: SEXTUPOLE, L=SLENGTH, K2=K2.SARCD2
 LS:=0.15
 DARCF:   DRIFT, L=4.0!LENGTHBF
 DARCD:   DRIFT, L=0.5!LENGTHBD
 DARCS1:   DRIFT, L=LS!0.15
 DARCS2:   DRIFT, L=0.15
 DARCFS:   DRIFT, L=4.0-LS-SLENGTH!LENGTHBF-0.2-SLENGTH
 DARCDS:   DRIFT, L=0.5-0.15-SLENGTH!LENGTHBD-0.2-SLENGTH
  
 ARCCEll: LINE=(QARCF,DARCS1,SARCF,DARCFS,BARC,DARCD,QARCD,QARCD,DARCS2,&
                SARCD,DARCDS,BARC,DARCF,QARCF)
 ARCCEll2: LINE=(QARCF,DARCS1,SARCF,DARCFS,BARC,DARCD,QARCD,&
                 QARCD,DARCS2,SARCD,DARCDS,BARC,DARCF,QARCF,&
                 QARCF,DARCF,BARC,DARCD,QARCD,&
                 QARCD,DARCS2,SARCD,DARCDS,BARC,DARCF,QARCF)
 ARCCEll3: LINE=(QARCF,DARCS1,SARCF2,DARCFS,BARC,DARCD,QARCD,&
                 QARCD,DARCS2,SARCD2,DARCDS,BARC,DARCF,QARCF,&
                 QARCF,DARCF,BARC,DARCD,QARCD,&
                 QARCD,DARCS2,SARCD2,DARCDS,BARC,DARCF,QARCF)              
 ARC: LINE=(83*ARCCEll)
 !ARC: LINE=(36*ARCCEll2)
 !ARC: LINE=(9*(2*ARCCEll2,2*ARCCEll3))
  !**** RF ********

  DRFC1:   DRIFT, L=2.5
  DRFC2:   DRIFT, L=3.0
  DRFC3:   DRIFT, L=3.5

  QRFCF:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QRFCF
  QRFCD:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QRFCD

  RF_ON  := 1

  VRFC:   RFCAVITY, L=0.2306096, VOLT=RFVOLT, LAG=RFPHSE, HARMON=7065

  RFCELL:     LINE=( QRFCF, DRFC3, &
                  VRFC,      DRFC2, &
                  VRFC,      DRFC1, &
                  QRFCD, DRFC3, &
                  VRFC,      DRFC2, &
                  VRFC,      DRFC1 )
                  
  RFSEC:   LINE=(3*RFCELL)
  
  ! ****CCH (circumference correction chicane)
  
  DCCH0:   DRIFT, L=1
  DCCH1:   DRIFT, L=3
  DCCH2:   DRIFT, L=1.5
  DCCH3:   DRIFT, L=0.5
  DCCH4:   DRIFT, L=0.5
  

  ANGCCH:= ANGARCB/2

  BCCH1:   SBEND, L=1.5!BLENGTH/2, ANGLE=ANGCCH, E1=ANGCCH, E2=0
  BCCH2:   SBEND, L=1.5!BLENGTH/2, ANGLE=-ANGCCH, E1=-ANGCCH, E2=0

  QCCHF:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QCCHF
  QCCHD:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QCCHD

  CCHCELL:    LINE=( DCCH0,QCCHF, DCCH1, &
                  QCCHD, DCCH2, &
                  -BCCH1,      DCCH4, &
                  BCCH2,      DCCH3, &
                  -BCCH2,      DCCH4, &
                  BCCH1,      DCCH3, &
                  -BCCH1,      DCCH4, &
                  BCCH2,      DCCH3, &
                  -BCCH2,      DCCH4, &
                  BCCH1,      DCCH2, &
                  QCCHD, DCCH1, &
                  QCCHF,DCCH0 )
  
  CCH:     LINE=(  2*CCHCELL)
  ! ************WIG (wiggler magnet)

  WIGBMAX := 1.6  ! Peak wiggler field (T)
  WIGPERD := 0.4  ! Wiggler period (m)
  LWIG=0.1
  WANGLE  := WIGBMAX*(WIGPERD/4)*CLIGHT/E0/1e9  ! Bending angle in one pole
  
  DWIG:  DRIFT, L=0.1
  DWIGE:  DRIFT, L=0.025

  BWIGM1:  SBEND, L=LWIG, ANGLE=WANGLE,   E1=WANGLE/2, E2=WANGLE/2
  BWIGM2:  SBEND, L=LWIG, ANGLE=-WANGLE,   E1=-WANGLE/2, E2=-WANGLE/2
  BWIGE1: SBEND, L=LWIG/2, ANGLE=-WANGLE/2, E1=0, E2=-WANGLE/2
  BWIGE2: SBEND, L=LWIG/2, ANGLE=WANGLE/2, E1=WANGLE/2, E2=0
  BWIGE22: SBEND, L=LWIG/2, ANGLE=WANGLE/2, E1=0, E2=WANGLE/2
  BWIGE21: SBEND, L=LWIG/2, ANGLE=-WANGLE/2, E1=-WANGLE/2, E2=0
  
  WIG:    LINE=(BWIGE1,DWIGE,5*(BWIGM1,DWIG,BWIGM2,DWIG),&
               BWIGM1,DWIG,BWIGM2,DWIGE,BWIGE2)
  WIG2:  LINE=(BWIGE22,DWIGE,5*(BWIGM2,DWIG,BWIGM1,DWIG),&
               BWIGM2,DWIG,BWIGM1,DWIGE,BWIGE21)
               
  DWIGC2:  DRIFT, L=0.5!LDWIGC2
  DWIGC1:  DRIFT, L=0.5!LDWIGC1

  QWIGCF:  QUADRUPOLE, L=QLENGTH, K1=K1.QWIGCF
  QWIGCD:  QUADRUPOLE, L=QLENGTH, K1=K1.QWIGCD

  WIGCELL:    LINE=(QWIGCF, DWIGC1, &
                 WIG,        DWIGC2, &
                 QWIGCD, QWIGCD,DWIGC2, &
                WIG2,    DWIGC1, QWIGCF)
  
  WIGSEC: LINE=(20*WIGCELL)
  
  !--------1---------2---------3---------4---------5---------6---------7---------8
! INJ (injection) and EXT (extraction)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DINJ1:   DRIFT, L=13.00   !LDINJ1
  DINJ2:   DRIFT, L=5.00     !LDINJ2
  DINJ3:   DRIFT, L=8.50
  DINJ4:   DRIFT, L= 0.25
  DINJ5:   DRIFT, L= 0.25
  DINJ6:   DRIFT, L= 7.25
  DINJ7:   DRIFT, L= 0.50
  DINJ8:   DRIFT, L= 7.25  
  DINJK:   DRIFT, L= 0.20


! Kickers

  KINJ1:   HKICKER, L=0.30, KICK=0.0

! Septa

  PINJ1:   HKICKER, L=1.00, KICK=0.0
  PINJ2:   HKICKER, L=1.00, KICK=0.0


! Quadrupoles

  QINJ1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QINJ1
  QINJ2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QINJ2


! Beam lines

  IJ0:     LINE=(             DINJ1, &
                  QINJ1, DINJ2, &
                  QINJ2, DINJ3,DINJ3, &
                  QINJ2, DINJ2, &
                  QINJ1, DINJ1 )

  IJP:     LINE=(             DINJ1, &
                  QINJ1, DINJ2, &
                  QINJ2, DINJ6, &
                  PINJ1,      DINJ7, &
                  PINJ2,      DINJ8, &
                  QINJ2, DINJ2, &
                  QINJ1, DINJ1 )

  KCKMD:   LINE=( DINJK, KINJ1 )
 

  IJK:     LINE=(             DINJ1, &
                  QINJ1, DINJ2, &
                  QINJ2, DINJ4, &
               33*KCKMD,      DINJ5, &
                  QINJ2, DINJ2, &
                  QINJ1, DINJ1 )

  INJEXT:     LINE=( IJP, IJK, IJK,IJP)
 ! INJEXT:     LINE=( IJP, IJK, IJK,IJP,IJ0)
  
!--------1---------2---------3---------4---------5---------6---------7---------8
! PHT (phase trombone)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DPHT:   DRIFT, L=6.0!LDPHT


! Quadrupoles

  QPHT1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHT1
  QPHT2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHT2
  QPHT3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHT3
  QPHT4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHT4
  QPHT5:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHT5
  QPHT6:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHT6


! Beam lines

  PHT:     LINE=( QPHT1, DPHT, &
                  QPHT2, DPHT, &
                  QPHT3, DPHT, &
                  QPHT4, DPHT, &
                  QPHT5, DPHT, &
                  QPHT6, DPHT )
!--------1---------2---------3---------4---------5---------6---------7---------8
! PHTI (phase trombone)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DPHTI:   DRIFT, L=6.0!LDPHT


! Quadrupoles

  QPHTI1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHTI1
  QPHTI2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHTI2
  QPHTI3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHTI3
  QPHTI4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHTI4
  QPHTI5:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHTI5
  QPHTI6:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QPHTI6


! Beam lines

  PHTI:     LINE=( QPHTI1, DPHTI, &
                  QPHTI2, DPHTI, &
                  QPHTI3, DPHTI, &
                  QPHTI4, DPHTI, &
                  QPHTI5, DPHTI, &
                  QPHTI6, DPHTI )
!--------1---------2---------3---------4---------5---------6---------7---------8
! DSP (dispersion suppressor)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DSARC:   DRIFT, L=SLENGTH
! Bends
  K0DSP := 0.495418440273
  ANGDSP1:= ANGARCB*K0DSP
  ANGDSP2:= ANGARCB*(1-K0DSP)
  BDSP1:   SBEND, L=BLENGTH, ANGLE=ANGDSP1, E1=ANGDSP1/2, E2=ANGDSP1/2
  BDSP2:   SBEND, L=BLENGTH, ANGLE=ANGDSP2, E1=ANGDSP2/2, E2=ANGDSP2/2


! Quadrupoles

  QDSP1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSP1
  QDSP2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSP2
  QDSP3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSP3
  QDSP4:   QUADRUPOLE, L=QLENGTH, K1=K1.QDSP4


! Beam lines
! ARCCEll: LINE=(QARCF,DARCS1,SARCF,DARCFS,BARC,DARCD,QARCD,QARCD,DARCS2,&
!                SARCD,DARCDS,BARC,DARCF,QARCF)
                
  DSP:     LINE=( QARCF,DARCS1,DSARC,DARCFS,BDSP1,DARCD,QDSP1,&
                 DARCS2,DSARC,DARCDS,BDSP1,DARCF,QDSP2,&
                 DARCS1,DSARC,DARCFS,BDSP2,DARCD,QDSP3,&
                 DARCS2,DSARC,DARCDS,BDSP2,DARCF,QDSP4)

   DSPPHT:  LINE=(DSP,PHT)  
!--------1---------2---------3---------4---------5---------6---------7---------8
! MDSPPHT  (matching from DSP to phase trombone)
!--------1---------2---------3---------4---------5---------6---------7---------8
! Drifts

  DMDP1:   DRIFT, L=4.5!LDMDP!
  DMDP2:   DRIFT, L=4.5!LDMDP!
  DMDP3:   DRIFT, L=7.7!LDMDP2!
  DMDP4:   DRIFT, L=8.3!LDMDP2!
  DMDP5:   DRIFT, L=8.3!LDMDP2!
! Quadrupoles

  QMDP1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDP1
  QMDP2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDP2
  QMDP3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDP3
  QMDP4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDP4


! Beam lines


 MDSPPHT:  LINE=( QDSP4,DMDP1,QMDP1,  &
                  DMDP2,QMDP2,  &
                  DMDP3,QMDP3,  &
                  DMDP4,QMDP4,DMDP5 )
 MDPTEST: LINE=(DSP,MDSPPHT,PHT)
!--------1---------2---------3---------4---------5---------6---------7---------8
! MPI  (matching from phase trombone to injection)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMPI1:   DRIFT, L=9!LDMPI1
  DMPI2:   DRIFT, L=11!LDMPI2
  DMPI3:   DRIFT, L=9!LDMPI3

! Quadrupoles

  QMPI1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPI1
  QMPI2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPI2
  QMPI3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPI3
  QMPI4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPI4


! Beam lines

  MPI:     LINE=( QMPI1, DMPI1, &
                  QMPI2, DMPI2, &
                  QMPI3, DMPI3, &
                  QMPI4 )
  MPIINJEXT: LINE=(MPI,INJEXT)
  
!--------1---------2---------3---------4---------5---------6---------7---------8
! IFD (fodo structure)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

 DIFD:   DRIFT, L=12.0

! Quadrupoles

  QIFD1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QIFD
  QIFD2:   QUADRUPOLE, L=2*QLENGTH, K1=-K1.QIFD


! Beam lines

  IFD:     LINE=( QIFD1,  DIFD, QIFD2,  DIFD  )

!--------1---------2---------3---------4---------5---------6---------7---------8
! MIF  (matching from injection to IFD {FODO section within inj straight})
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMIF1:   DRIFT, L=5!LDMIF1
  DMIF2:   DRIFT, L=7!LDMIF2
  DMIF3:   DRIFT, L=7!LDMIF3
  DMIF4:   DRIFT, L=7!LDMIF4


! Quadrupoles

  QMIF1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIF1
  QMIF2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIF2
  QMIF3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIF3
  QMIF4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIF4


! Beam lines

  MIF:     LINE=( QMIF1, DMIF1, &
                  QMIF2, DMIF2, &
                  QMIF3, DMIF3, &
                  QMIF4, DMIF4 )

 MIFT:  LINE=(MIF,IFD)   
 !--------1---------2---------3---------4---------5---------6---------7---------8
! MIC  (matching from injection to CCH)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMIC1:   DRIFT, L=3.5!LDMIC1
  DMIC2:   DRIFT, L=9.84!LDMIC2
  DMIC3:   DRIFT, L=2.7!LDMIC3
  DMIC4:   DRIFT, L=2.8!LDMIC4


! Quadrupoles

  QMIC1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIC1
  QMIC2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIC2
  QMIC3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIC3
  QMIC4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMIC4


! Beam lines

  MIC:     LINE=( QMIC1, DMIC1, &
                  QMIC2, DMIC2, &
                  QMIC3, DMIC3, &
                  QMIC4, DMIC4 )

 MICT:  LINE=(MIC,CCHCELL)         
!--------1---------2---------3---------4---------5---------6---------7---------8
! MFC (matching from FODO into circumference correction chicane)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMFC1:   DRIFT, L=5.8+2!LDMFC+2
  DMFC2:   DRIFT, L=5.8+3!LDMFC+3 
  DMFC3:   DRIFT, L=5.8!LDMFC 
  DMFC4:   DRIFT, L=5.8!LDMFC 

! Quadrupoles

  QMFC1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMFC1
  QMFC2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMFC2
  QMFC3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMFC3
  QMFC4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMFC4


! Beam lines

  MFC:     LINE=( QMFC1,  DMFC1, &
                  QMFC2,  DMFC2, &
                  QMFC3,  DMFC3, &
                  QMFC4, DMFC4)
 MFCT:   LINE=(MFC,CCHCELL)
           
!--------1---------2---------3---------4---------5---------6---------7---------8
! DSPC (dispersion suppressor to chincane)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DDSPC1:   DRIFT, L=2.2!LDSPC!
  DDSPC2:   DRIFT, L=3.6!LDSPC1!     
  DDSPC3:   DRIFT, L=3.1!LDSPC2!
  DDSPC4:   DRIFT, L=2.6!LDSPC3!
  DDSPC5:   DRIFT, L=2.6!LDSPC3!
  DDSPC6:   DRIFT, L=2.6!LDSPC3!
  DDSPC7:   DRIFT, L=2.6!LDSPC3!

! Bends

  ANGDSPC1:= ANGARCB*K0DSPC
  ANGDSPC2:= ANGARCB*(1-K0DSPC)
  BDSPC1:   SBEND, L=BLENGTH, ANGLE=ANGDSPC1, E1=ANGDSPC1/2, E2=ANGDSPC1/2
  BDSPC2:   SBEND, L=BLENGTH, ANGLE=ANGDSPC2, E1=ANGDSPC2/2, E2=ANGDSPC2/2
  
! Quadrupoles

  QDSPC1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC1
  QDSPC2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC2
  QDSPC3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC3
  QDSPC4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC4
  QDSPC5:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC5
  QDSPC6:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC6
  QDSPC7:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPC7

! Beam lines

  DSPC:     LINE=( QARCF,DDSPC1, BDSPC1,DDSPC1 , &
                  QDSPC1, DDSPC2,QDSPC2,DDSPC2,QDSPC3,DDSPC3, BDSPC2,DDSPC3 ,&
                  QDSPC4,DDSPC4 ,&
                  QDSPC5,DDSPC5, &
                  QDSPC6,DDSPC6, &
                  QDSPC7,DDSPC7)
 DSPCT:  LINE=(DSPC,CCHCELL) 
 !--------1---------2---------3---------4---------5---------6---------7---------8
! MDSPC  (matching from DSP to chicane)
!--------1---------2---------3---------4---------5---------6---------7---------8
! Drifts

  DMDC1:   DRIFT, L=8.8!LDMDC!
  DMDC2:   DRIFT, L=8.8!LDMDC!
  DMDC3:   DRIFT, L=4.8!LDMDC1!
  DMDC4:   DRIFT, L=2.6!LDMDC2!
  DMDC5:   DRIFT, L=1.0!LDMDC3!
! Quadrupoles

  QMDC1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDC1
  QMDC2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDC2
  QMDC3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDC3
  QMDC4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDC4


! Beam lines


 MDSPC:  LINE=( QDSP4,DMDC1,QMDC1,  &
                  DMDC2,QMDC2,  &
                  DMDC3,QMDC3,  &
                  DMDC4,QMDC4,DMDC5 )
 MDCTEST: LINE=(DSP,MDSPC,CCHCELL)  
!--------1---------2---------3---------4---------5---------6---------7---------8
! MDSPW  (matching from DSP to wiggler)
!--------1---------2---------3---------4---------5---------6---------7---------8
! Drifts

  DMDW1:   DRIFT, L=2.4!1.5!LDMDW!
  DMDW2:   DRIFT, L=1.2!3.0!LDMDW1!
  DMDW3:   DRIFT, L=3.0!1.8!LDMDW2!
  DMDW4:   DRIFT, L=3.0!1.8!LDMDW2!
  DMDW5:   DRIFT, L=3.0!1.8!LDMDW2!
! Quadrupoles

  QMDW1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDW1
  QMDW2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDW2
  QMDW3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDW3
  QMDW4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMDW4


! Beam lines


 MDSPW:  LINE=( QDSP4,DMDW1,QMDW1,  &
                  DMDW2,QMDW2,  &
                  DMDW3,QMDW3,  &
                  DMDW4,QMDW4,DMDW5 )
 MDWTEST: LINE=(DSP,MDSPW,WIGCELL)   
 !--------1---------2---------3---------4---------5---------6---------7---------8
! DSPW (dispersion suppressor to WIGGLER)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DDSPW1:   DRIFT, L=2.6!LDSPW!
  DDSPW2:   DRIFT, L=3.5!LDSPW1!     
  DDSPW3:   DRIFT, L=2.0!LDSPW2!
  DDSPW4:   DRIFT, L=2.5!LDSPW3!
  DDSPW5:   DRIFT, L=2.5!LDSPW3!
  DDSPW6:   DRIFT, L=2.5!LDSPW3!
  DDSPW7:   DRIFT, L=2.5!LDSPW3!

! Bends

  ANGDSPW1:= ANGARCB*K0DSPW
  ANGDSPW2:= ANGARCB*(1-K0DSPW)
  BDSPW1:   SBEND, L=BLENGTH, ANGLE=ANGDSPW1, E1=ANGDSPW1/2, E2=ANGDSPW1/2
  BDSPW2:   SBEND, L=BLENGTH, ANGLE=ANGDSPW2, E1=ANGDSPW2/2, E2=ANGDSPW2/2
  
! Quadrupoles

  QDSPW1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW1
  QDSPW2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW2
  QDSPW3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW3
  QDSPW4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW4
  QDSPW5:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW5
  QDSPW6:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW6
  QDSPW7:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QDSPW7

! Beam lines

  DSPW:     LINE=( QARCF,DDSPW1, BDSPW1,DDSPW1 , &
                  QDSPW1, DDSPW2,QDSPW2,DDSPW2,QDSPW3,DDSPW3, BDSPW2,DDSPW3 ,&
                  QDSPW4,DDSPW4 ,&
                  QDSPW5,DDSPW5, &
                  QDSPW6,DDSPW6, &
                  QDSPW7,DDSPW7,QWIGCF)
 DSPWT:  LINE=(DSPW,WIGCELL) 
 
!--------1---------2---------3---------4---------5---------6---------7---------8
! MPR (matching PHT to RF)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMPR1:   DRIFT, L=4.0!LDMPR
  DMPR2:   DRIFT, L=5.8!LDMPR


! Quadrupoles

  QMPR1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPR1
  QMPR2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPR2
  QMPR3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPR3
  QMPR4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMPR4


! Beam lines

  MPR:     LINE=( QMPR1,  DMPR1, &
                  QMPR3,  DMPR1, &
                  QMPR2,  DMPR2, &
                  QMPR4,  DMPR2  )
   
  MPRT: LINE=(MPR,RFSEC,MRC,CCH)    
!--------1---------2---------3---------4---------5---------6---------7---------8
! MRC (matching from RF into circumference correction chicane)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMRC1:   DRIFT, L=7.0!LDMRC
  DMRC2:   DRIFT, L=7.0
  DMRC3:   DRIFT, L=5.0
! Quadrupoles

  QMRC1:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMRC1
  QMRC2:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMRC2
  QMRC3:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMRC3
  QMRC4:   QUADRUPOLE, L=2*QLENGTH, K1=K1.QMRC4


! Beam lines

  MRC:     LINE=( QMRC1,  DMRC1, &
                  QMRC2,  DMRC2, &
                  QMRC3,  DMRC3, &
                  QMRC4 )
  MRCT: LINE=(MRC,CCH)  
  
!--------1---------2---------3---------4---------5---------6---------7---------8
! MCW (matching from CCH into wiggler cell 
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMCW1:  DRIFT, L=8.3-1.527315!LDMCW-1
  DMCW2:  DRIFT, L=8.3-2!LDMCW-2
  DMCW3:  DRIFT, L=8.3!LDMCW
  DMCW4:  DRIFT, L=8.3!LDMCW

! Quadrupoles

  QMCW1:  QUADRUPOLE, L=2*QLENGTH, K1=K1.QMCW1
  QMCW2:  QUADRUPOLE, L=2*QLENGTH, K1=K1.QMCW2
  QMCW3:  QUADRUPOLE, L=2*QLENGTH, K1=K1.QMCW3
  QMCW4:  QUADRUPOLE, L=2*QLENGTH, K1=K1.QMCW4



! Beamline

  MCW:    LINE=( QMCW1, DMCW1, &
                 QMCW2, DMCW2, &
                 QMCW3, DMCW3, &
                 QMCW4, DMCW4,QWIGCF)
 
  MCWT: LINE=(MCW,WIGCELL)
 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
 !STRSECI: LINE=(DSP,4*PHT,MPI,INJEXT,MIC,3*CCHCELL,-DSPC)
 !STRSECW: LINE=(DSP,5*PHT,MPR,RFSEC,MRC,3*CCHCELL,MCW,WIGSEC,-DSPW)
 
 STRSECI: LINE=(MDSPPHT,1*PHTI,MPI,INJEXT,MIC,2*CCHCELL,-MDSPC)
 STRSECIt: LINE=(MDSPPHT,1*PHT,MPI,INJEXT,MIC,2*CCHCELL,-MDSPC)
 STRSECW: LINE=(MDSPPHT,1*PHT,MPR,RFSEC,MRC,2*CCHCELL,MCW,WIGSEC,-MDSPW)
 
 !ERING:  LINE=(ARC,STRSECI,ARC,STRSECW)
 ERING:  LINE=(-DSP,ARC,DSP,STRSECIt,-DSP,ARC,DSP,STRSECW)
 
 RETURN