! ILCDR LATTICE "DSB" for 3.2 km ring
! M. Biagini (LNF) October 2008

! modified : straight sections from  DCO4
! S. Guiducci December 2009

! Work in progress for new version       February 2011  

  E0      := 5.0           ! nominal beam energy (GeV)

  BLENGTH := 2.00          ! length of standard bending magnet
  QLENGTH := 0.30          ! length of standard quadrupole
  SLENGTH := 0.25          ! length of standard sextupole

  ANGARCB := TWOPI/192     ! angle of arc bending magnet (192 arc (fodo) cells)


  scl := 1.2643 ! scale coefficient to squeeze length of the drifts in the MDW


!--------1---------2---------3---------4---------5---------6---------7---------8
! Instrumentation and correction components
!------------------------------------------------------------------------------
! For matching iteration here LDBPM:=0, LDCOR:= 0, LCOR:= 0
!--------1---------2---------3---------4---------5---------6---------7---------8
! Drift from quadrupole to beam position monitor

  LDBPM := 0.0
  DBPM:    DRIFT, L=LDBPM

! Beam position monitor

  BPMRNG:  MONITOR

! Drift from orbit corrector to quadrupole

  LDCOR := 0.0
  DCOR:    DRIFT, L=LDCOR

! Orbit corrector

  LCOR  := 0.0
  CORRNG:  KICKER, L=LCOR, HKICK=0, VKICK=0

! Skew quadrupole (coupling corrector)

  SKQRNG: QUADRUPOLE, L=0.2, K1=0.0, TILT

!-------------------------------------------------------------------------------
! Instrumentation and correction components
!-------------------------------------------------------------------------------
   LDBPM := 0.25  !Drift from quadrupole to beam position monitor
   LDCOR := 0.1   !Drift from orbit corrector to quadrupole
   LCOR  := 0.15  !Orbit corrector length
!-------------------------------------------------------------------------------

! Corrector, quad and BPM

  CQB(Q1): LINE=(CORRNG,DCOR,Q1,DBPM,BPMRNG)


!--------1---------2---------3---------4---------5---------6---------7---------8
! PHT (phase trombone)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

!  DPHT1:   DRIFT, L=10.6 -LDBPM-LCOR-LDCOR
!  DPHT1:   DRIFT, L=20.0 -LDBPM-LCOR-LDCOR
!   DPHT1I:   DRIFT, L=19.5 -LDBPM-LCOR-LDCOR
   DPHT1:   DRIFT, L=19.95 -LDBPM-LCOR-LDCOR
   DPHT1I:   DRIFT, L=18.9 -LDBPM-LCOR-LDCOR

! Quadrupoles

  QPHTR1:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHTR1
  QPHTR2:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHTR2

  QPHT1:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHT1
  QPHT2:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHT2
  QPHT3:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHT3
  QPHT4:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHT4
  QPHT5:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHT5
  QPHT6:   QUADRUPOLE, L=QLENGTH, K1=K1.QPHT6



! Beam lines

 PHTCR:     LINE=( CQB(QPHTR1), DPHT1, &
                   CQB(QPHTR2), DPHT1)

 PHTCI:     LINE=( CQB(QPHT1), DPHT1I, CQB(QPHT2), DPHT1I, &                  
                   CQB(QPHT3), DPHT1I, CQB(QPHT4), DPHT1I, &       
                   CQB(QPHT5), DPHT1I, CQB(QPHT6), DPHT1I)


comment
 PHTR:     LINE=( 4*(CQB(QPHT1), DPHT1, CQB(QPHT2), DPHT1, &                  
                     CQB(QPHT3), DPHT1, CQB(QPHT4), DPHT1, &       
                     CQB(QPHT5), DPHT1, CQB(QPHT6), DPHT1), & 
                     CQB(QPHT3), DPHT1, CQB(QPHT4), DPHT1, &       
                     CQB(QPHT5), DPHT1, CQB(QPHT6), DPHT1)
endcomment

 PHTR:     LINE=( 13*PHTCR)                   
                      
 PHTI:     LINE=( 4*PHTCI)
                   
                     


!--------1---------2---------3---------4---------5---------6---------7---------8
! MRC (matching from RF into circumference correction chicane)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMRC1:   DRIFT, L=6.0-LDBPM-LCOR-LDCOR


! Quadrupoles

  QMRC1:   QUADRUPOLE, L=QLENGTH, K1=K1.QMRC1
  QMRC2:   QUADRUPOLE, L=QLENGTH, K1=K1.QMRC2
  QMRC3:   QUADRUPOLE, L=QLENGTH, K1=K1.QMRC3
  QMRC4:   QUADRUPOLE, L=QLENGTH, K1=K1.QMRC4


! Beam lines

  MRC:     LINE=( CQB(QMRC1),  DMRC1, &
                  CQB(QMRC2),  DMRC1, &
                  CQB(QMRC3),  DMRC1, &
                  CQB(QMRC4) )

  
!--------1---------2---------3---------4---------5---------6---------7---------8
! MFC (matching from IFD {within inj} into circumference correction chicane)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMFC1:   DRIFT, L=5.302767-LDBPM-LCOR-LDCOR


! Quadrupoles

  QMFC1:   QUADRUPOLE, L=QLENGTH, K1=K1.QMFC1
  QMFC2:   QUADRUPOLE, L=QLENGTH, K1=K1.QMFC2
  QMFC3:   QUADRUPOLE, L=QLENGTH, K1=K1.QMFC3
  QMFC4:   QUADRUPOLE, L=QLENGTH, K1=K1.QMFC4


! Beam lines

  MFC:     LINE=( CQB(QMFC1),  DMFC1, &
                  CQB(QMFC2),  DMFC1, &
                  CQB(QMFC3),  DMFC1, &
                  CQB(QMFC4) )


!--------1---------2---------3---------4---------5---------6---------7---------8
! CCH (circumference correction chicane)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DCCH0:   DRIFT, L= 4.00      -LCOR-LDCOR
  DCCH1:   DRIFT, L= 4.00-LDBPM-LCOR-LDCOR
  DCCH2:   DRIFT, L= 3.878-LDBPM-LCOR-LDCOR
  DCCH3:   DRIFT, L= 0.50-LDBPM
  DCCH4:   DRIFT, L= 1.00
  DCCH5:   DRIFT, L= 0.50
  DCCH6:   DRIFT, L= 3.00
  DCCH7:   DRIFT, L= 0.50      -LCOR-LDCOR
  DCCH8:   DRIFT, L= 4.00-LDBPM


! Bends

  ANGCCH1:= ANGARCB/2
  ANGCCH2:= -ANGARCB/2

  BCCH1:   SBEND, L=BLENGTH/2, ANGLE=ANGCCH1, E1=ANGCCH1/2, E2=ANGCCH1/2
  BCCH2:   SBEND, L=BLENGTH/2, ANGLE=ANGCCH2, E1=ANGCCH2/2, E2=ANGCCH2/2


! Quadrupoles

  QCCH1:   QUADRUPOLE, L=QLENGTH, K1=K1.QCCH1
  QCCH2:   QUADRUPOLE, L=QLENGTH, K1=K1.QCCH2


! Beam lines

  CCH1:    LINE=(             DCCH1, &
                  CQB(QCCH1), DCCH2, &
                  CQB(QCCH2), DCCH3, &
                  BCCH1,      DCCH4, &
                  BCCH2,      DCCH5, &
                  BCCH2,      DCCH6, &
                  BCCH1,      DCCH5, &
                  BCCH1,      DCCH4, &
                  BCCH2,      DCCH7, &
                  CQB(QCCH2), DCCH2, &
                  CQB(QCCH1), DCCH8 )

  CCH0:    LINE=(             DCCH0, &
                  CQB(QCCH1), DCCH2, &
                  CQB(QCCH2), DCCH3, &
                  BCCH1,      DCCH4, &
                  BCCH2,      DCCH5, &
                  BCCH2,      DCCH6, &
                  BCCH1,      DCCH5, &
                  BCCH1,      DCCH4, &
                  BCCH2,      DCCH7, &
                  CQB(QCCH2), DCCH2, &
                  CQB(QCCH1), DCCH8 )

  CCH2:    LINE=(             DCCH0, &
                  CQB(QCCH1), DCCH2, &
                  CQB(QCCH2), DCCH3, &
                  BCCH1,      DCCH4, &
                  BCCH2,      DCCH5, &
                  BCCH2,      DCCH6, &
                  BCCH1,      DCCH5, &
                  BCCH1,      DCCH4, &
                  BCCH2,      DCCH7, &
                  CQB(QCCH2), DCCH2, &
                  CQB(QCCH1), DCCH1 )


  CCH:     LINE=( CCH1, 2*CCH0, CCH2 )


!--------1---------2---------3---------4---------5---------6---------7---------8
! IFD (fodo structure)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

 DIFD:   DRIFT, L=10.355280-LDBPM-LCOR-LDCOR


! Quadrupoles

  QIFD1:   QUADRUPOLE, L=QLENGTH, K1=K1.QIFD1
  QIFD2:   QUADRUPOLE, L=QLENGTH, K1=K1.QIFD2


! Beam lines

  IFD:     LINE=( CQB(QIFD1),  DIFD, &
                  CQB(QIFD2),  DIFD  )



!--------1---------2---------3---------4---------5---------6---------7---------8
! C (rf)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

!  D1:   DRIFT, L= 3.06277573      -LCOR-LDCOR
!  DRFC2:   DRIFT, L= 3.11322937
!  DRFC3:   DRIFT, L= 3.06277573-LDBPM

  DRFC1:   DRIFT, L= 3.20      -LCOR-LDCOR
  DRFC2:   DRIFT, L= 3.25
  DRFC3:   DRIFT, L= 3.20-LDBPM

  DRFCV:   DRIFT, L=0.2306096  !  RF cavity length 


! Quadrupoles

  QRFC1:   QUADRUPOLE, L=QLENGTH, K1=K1.QRFC1
  QRFC2:   QUADRUPOLE, L=QLENGTH, K1=K1.QRFC2


! RF cavities

  RF_ON  := 1

  VRFC1:   RFCAVITY, L=0.2306096, VOLT=RFVOLT, LAG=RFPHSE, HARMON=7021


! Beam lines

  RFCV:     LINE=( CQB(QRFC1), DRFC3, &
                  VRFC1,      DRFC2, &
                  VRFC1,      DRFC1, &
                  CQB(QRFC2), DRFC3, &
                  VRFC1,      DRFC2, &
                  VRFC1,      DRFC1 )

!  RF cells no cavities

  RFC:     LINE=( CQB(QRFC2), DRFC3, &
                  DRFCV,      DRFC2, &
                  DRFCV,      DRFC1, &
                  CQB(QRFC1), DRFC3, &
                  DRFCV,      DRFC2, &
                  DRFCV,      DRFC1 )

!  Half RF cell no cavities 1

  HRFC1:     LINE=( CQB(QRFC1), DRFC3, &
                    DRFCV,      DRFC2, &
                    DRFCV,      DRFC1)

!  Half RF cell no cavities 2

  HRFC2:     LINE=( CQB(QRFC2), DRFC3, &
                    DRFCV,      DRFC2, &
                    DRFCV,      DRFC1 )


!--------1---------2---------3---------4---------5---------6---------7---------8
! MPR (matching PHT to RF)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

!  DMPR1:   DRIFT, L=5.816297-LDBPM-LCOR-LDCOR
!  DMPR2:   DRIFT, L=6.0-LDBPM-LCOR-LDCOR
 DMPR1:   DRIFT, L=5.65
 DMPR2:   DRIFT, L=5.65

! Quadrupoles

  QMPR1:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPR1
  QMPR2:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPR2
  QMPR3:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPR3
  QMPR4:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPR4


! Beam lines

  MPR:     LINE=( CQB(QMPR1),  DMPR1, &
                  CQB(QMPR3),  DMPR1, &
                  CQB(QMPR2),  DMPR2, &
                  CQB(QMPR4),  DMPR2  )


!--------1---------2---------3---------4---------5---------6---------7---------8
! WIG (wiggler magnet)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DWIG2:  DRIFT, L=0.06
  LWIG3 := 0.105
  DWIG3:  DRIFT, L=LWIG3


! Bends

  WIGBMAX := 1.9  ! Peak wiggler field (T)
  WIGPERD := 0.3  ! Wiggler period (m)
  WIGPLEN := 0.09 ! Wiggler pole length (m)

  WANGLE  := WIGBMAX*WIGPLEN*CLIGHT/E0/1e9  ! Bending angle in one pole
  FWA=0.902261    

  BWIGP:  SBEND, L=WIGPLEN, ANGLE=+WANGLE,   E1=+WANGLE/2, E2=+WANGLE/2
  BWIGM:  SBEND, L=WIGPLEN, ANGLE=-WANGLE,   E1=-WANGLE/2, E2=-WANGLE/2
  BWIGPH: SBEND, L=WIGPLEN/2, ANGLE=+WANGLE/2*FWA, E1=+WANGLE/4, E2=+WANGLE/4
  BWIGMH: SBEND, L=WIGPLEN/2, ANGLE=-WANGLE/2*FWA, E1=-WANGLE/4, E2=-WANGLE/4

! Beamlines

  WIGPRD: LINE=(BWIGM,DWIG2,BWIGP,DWIG2)

  WIG:    LINE=(BWIGPH,DWIG3,5*WIGPRD,BWIGM,DWIG2,BWIGP,DWIG3,BWIGMH)


!--------1---------2---------3---------4---------5---------6---------7---------8
! WGC (wiggler cell)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DWGC2:  DRIFT, L=0.75-LCOR-LDCOR
  DWGC1:  DRIFT, L=0.75-LDBPM

  DRWIG:  DRIFT, L=2.040  !  wiggler length

! Quadrupoles

  QWGC1:  QUADRUPOLE, L=QLENGTH, K1=K1.QWGC1
  QWGC2:  QUADRUPOLE, L=QLENGTH, K1=K1.QWGC2

  QWGC3:  QUADRUPOLE, L=QLENGTH, K1=K1.QWGC3
  QWGC4:  QUADRUPOLE, L=QLENGTH, K1=K1.QWGC4
  QWGC5:  QUADRUPOLE, L=QLENGTH, K1=K1.QWGC5
  QWGC6:  QUADRUPOLE, L=QLENGTH, K1=K1.QWGC6


! Beamlines

!  wiggler ON (1 cella FODO)
  WGC:    LINE=( CQB(QWGC1), DWGC1, &
                 WIG,        DWGC2, &
                 CQB(QWGC2), DWGC1, &
                -WIG,        DWGC2 )

!  wiggler OFF (2 celle FODO)
  WGC_OFF:    LINE=( CQB(QWGC3), DWGC1, DRWIG, DWGC2, &
                     CQB(QWGC4), DWGC1, DRWIG, DWGC2, &
                     CQB(QWGC5), DWGC1, DRWIG, DWGC2, &
                     CQB(QWGC6), DWGC1, DRWIG, DWGC2 )


!--------1---------2---------3---------4---------5---------6---------7---------8
! MDW (matching from CCH into wiggler cell {RF-WIG str} or PSD {INJ str})
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMDW1:  DRIFT, L=6.0*scl-LDBPM-LCOR-LDCOR
  DMDW2:  DRIFT, L=6.0*scl-LDBPM-LCOR-LDCOR
  DMDW3:  DRIFT, L=5.0*scl-LDBPM-LCOR-LDCOR
  DMDW4:  DRIFT, L=4.0*scl-LDBPM-LCOR-LDCOR

! Quadrupoles

  QMDW1:  QUADRUPOLE, L=QLENGTH, K1=K1.QMDW1
  QMDW2:  QUADRUPOLE, L=QLENGTH, K1=K1.QMDW2
  QMDW3:  QUADRUPOLE, L=QLENGTH, K1=K1.QMDW3
  QMDW4:  QUADRUPOLE, L=QLENGTH, K1=K1.QMDW4


! Beamline

  MDW:    LINE=( CQB(QMDW1), DMDW1, &
                 CQB(QMDW2), DMDW2, &
                 CQB(QMDW3), DMDW3, &
                 CQB(QMDW4), DMDW4 )


!--------1---------2---------3---------4---------5---------6---------7---------8
! PSD (reversed dispersion suppressor)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DPSD1:   DRIFT, L= 1.50      -LCOR-LDCOR
  DPSD2:   DRIFT, L= 1.30-LDBPM
  DPSD3:   DRIFT, L= 4.00-LDBPM-LCOR-LDCOR
  DPSD4:   DRIFT, L= 1.70-LDBPM-LCOR-LDCOR
  DPSD5:   DRIFT, L= 5.65      -LCOR-LDCOR

  DPSD6:   DRIFT, L= 2.50-LDBPM
  DPSD7:   DRIFT, L= 2.80-LDBPM-LCOR-LDCOR
  DPSD8:   DRIFT, L= 5.80-LDBPM-LCOR-LDCOR
  DPSD9:   DRIFT, L=10.40-LDBPM-LCOR-LDCOR
  DPSDA:   DRIFT, L= 2.60


! Bends

  ANGPSD1:= ANGARCB*0.25
  ANGPSD2:= ANGARCB*0.75

  BPSD1:   SBEND, L=BLENGTH, ANGLE=ANGPSD1, E1=ANGPSD1/2, E2=ANGPSD1/2
  BPSD2:   SBEND, L=BLENGTH, ANGLE=ANGPSD2, E1=ANGPSD2/2, E2=ANGPSD2/2


! Quadrupoles

  QPSD0:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD0
  QPSD1:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD1
  QPSD2:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD2
  QPSD3:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD3

  QPSD4:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD4
  QPSD5:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD5
  QPSD6:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD6
  QPSD7:   QUADRUPOLE, L=QLENGTH, K1=K1.QPSD7


! Beam lines

  PSD:     LINE=(             DPSDA, &
                  CQB(QPSD7), DPSD9, &
                  CQB(QPSD6), DPSD8, &
                  CQB(QPSD5), DPSD7, &
                  CQB(QPSD4), DPSD6, &
                  BPSD2,      DPSD5, &
                  CQB(QPSD3), DPSD4, &
                  CQB(QPSD2), DPSD3, &
                  CQB(QPSD1), DPSD2, &
                  BPSD1,      DPSD1, & 
                  CORRNG,     DCOR,  &
                      QPSD0 )

!--------1---------2---------3---------4---------5---------6---------7---------8
!  (injection) and EXT (extraction)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DINJ0:   DRIFT, L=10.50
  DINJ1:   DRIFT, L=11.00-LDBPM-LCOR-LDCOR
  DINJ2:   DRIFT, L= 6.70-LDBPM-LCOR-LDCOR
  DINJ3:   DRIFT, L=17.00-LDBPM-LCOR-LDCOR
  DINJ4:   DRIFT, L= 5*0.5 + 0.25-LDBPM
  DINJ5:   DRIFT, L= 5*0.5 + 0.25      -LCOR-LDCOR
  DINJ6:   DRIFT, L= 7.25-LDBPM
  DINJ7:   DRIFT, L= 0.50
  DINJ8:   DRIFT, L= 7.25      -LCOR-LDCOR
  DINJK:   DRIFT, L= 0.20


! Kickers

  KINJ1:   HKICKER, L=0.3, KICK=KICK.INJ

  KEXT1:   HKICKER, L=0.3, KICK=KICK.EXT

! Septa

  PINJ1:   HKICKER, L=1.0, KICK=KICK.PINJ1
  PINJ2:   HKICKER, L=1.0, KICK=KICK.PINJ2

  PEXT1:   HKICKER, L=1.0, KICK=KICK.PEXT1
  PEXT2:   HKICKER, L=1.0, KICK=KICK.PEXT2


! Quadrupoles

  QINJ1:   QUADRUPOLE, L=QLENGTH, K1=K1.QINJ1
  QINJ2:   QUADRUPOLE, L=QLENGTH, K1=K1.QINJ2


! Beam lines

  IJ0:     LINE=(             DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ3, &
                  CQB(QINJ2), DINJ2, &
                  CQB(QINJ1), DINJ0 )

  IJP:     LINE=(             DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ6, &
                  PINJ1,      DINJ7, &
                  PINJ2,      DINJ8, &
                  CQB(QINJ2), DINJ2, &
                  CQB(QINJ1), DINJ0 )

  KCKMD:   LINE=( DINJK, KINJ1 )
  KCKMDE:   LINE=( DINJK, KEXT1 )

  IJK:     LINE=(             DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ4, &
               23*KCKMD,      DINJ5, &
                  CQB(QINJ2), DINJ2, &
                  CQB(QINJ1), DINJ0 )


  EXK:     LINE=(             DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ4, &
               23*KCKMDE,     DINJ5, &
                  CQB(QINJ2), DINJ2, &
                  CQB(QINJ1), DINJ0 )


  EXP:     LINE=(             DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ6, &
                  PEXT2,      DINJ7, &
                  PEXT1,      DINJ8, &
                  CQB(QINJ2), DINJ2, &
                  CQB(QINJ1), DINJ0 )


  EX0:     LINE=(             DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ3, &
                  CQB(QINJ2), DINJ2, &
                  CQB(QINJ1), DINJ1 )



  INJ:     LINE=( IJ0, IJP, IJK)
  EXT:     LINE=( EXK, EXP, EX0)

!  Extraction line  (up to 1st Q-pole after septa)
  EXT_RTML:     LINE=( EXK,   DINJ1, &
                  CQB(QINJ1), DINJ2, &
                  CQB(QINJ2), DINJ6, &
                  PEXT2,      DINJ7, &
                  PEXT1,      DINJ8)

!--------1---------2---------3---------4---------5---------6---------7---------8
! MPI  (matching from phase trombone to injection)
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMPI2:   DRIFT, L=14.0
  DMPI3:   DRIFT, L=12.0 
  DMPI4:   DRIFT, L=14.0


! Quadrupoles

  QMPI1:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPI1
  QMPI2:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPI2
  QMPI3:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPI3
  QMPI4:   QUADRUPOLE, L=QLENGTH, K1=K1.QMPI4


! Beam lines

  MPI:     LINE=(  & 
                  CQB(QMPI1), DMPI2, &
                  CQB(QMPI2), DMPI3, &
                  CQB(QMPI3), DMPI4, &
                      QMPI4 )
!                  CQB(QMPI4) )



!--------1---------2---------3---------4---------5---------6---------7---------8
! MIF  (matching from injection to IFD {FODO section within inj straight})
!--------1---------2---------3---------4---------5---------6---------7---------8

! Drifts

  DMIF1:   DRIFT, L=5.00-LDBPM-LCOR-LDCOR
  DMIF2:   DRIFT, L=12.10-LDBPM-LCOR-LDCOR
  DMIF3:   DRIFT, L=5.00-LDBPM-LCOR-LDCOR
  DMIF4:   DRIFT, L=5.00-LDBPM-LCOR-LDCOR


! Quadrupoles

  QMIF1:   QUADRUPOLE, L=QLENGTH, K1=K1.QMIF1
  QMIF2:   QUADRUPOLE, L=QLENGTH, K1=K1.QMIF2
  QMIF3:   QUADRUPOLE, L=QLENGTH, K1=K1.QMIF3
  QMIF4:   QUADRUPOLE, L=QLENGTH, K1=K1.QMIF4


! Beam lines

  MIF:     LINE=( CQB(QMIF1), DMIF1, &
                  CQB(QMIF2), DMIF2, &
                  CQB(QMIF3), DMIF3, &
                  CQB(QMIF4), DMIF4 )

! ------------------------------------------------------------------------------
!New SuperB-like cells matching to DCO straights

! ==============================================================================
!----------------------------------------------------
! BPMs, KICKERs, and MARKERs
!----------------------------------------------------

M0: MARKER
MRK: MARKER
MRKL: MARKER
MRKA: MARKER
MRKAD: MARKER
MRKW: MARKER
MRKT: MARKER
MBSUP: MARKER
MSUP1: marker
MSUP0: marker

!----------------------------------------------------
! RF Cavities (drift)
!----------------------------------------------------

LRFCa = 4.0

!----------------------------------------------------
!  magnets
!----------------------------------------------------
! 
! main dipoles

! change dipole length
! LB = 5.4
 LBB = 1.35
 LB = 5.4 -2*LBB 


 BB:  SBEND, L = LB, ANGLE = THETA, K1 = 0.0, E1=0.5*THETA, E2=0.5*THETA
 BBpi:  SBEND, L = LB, ANGLE = THETpi, K1 = 0.0, E1=0.5*THETpi, E2=0.5*THETpi
 BBs: SBEND, L = lb, ANGLE = THETAs, K1 = 0.0, E1=0.5*THETAs, E2=0.5*THETAs

 !BB:  RBEND, L = LB, ANGLE = THETA, K1 = 0.0, E1=0., E2=0.
 !BBpi:  RBEND, L = LB, ANGLE = THETpi, K1 = 0.0, E1=0., E2=0.
 !BBs: RBEND, L = lb, ANGLE = THETAs, K1 = 0.0, E1=0., E2=0.


 LB0 = 2.0
 LMD0 = 0.4
 LMD1 = 0.2
 LMD2 = 6.783307071569
 LMD3 = 5.124909527754
 LMD4 = 5.795112579686
 LMD4S = 5.8
 LMD5 = 5.8
 LMD6 = 5.315132182892
 LMD7 = 5.79398166557
 LMD7S = 6.135059715599
 LMD8 = 0.2
 DDD = 0.17397089895

 ! quads

 LQ56:   CONSTANT = 0.280        ! length half PEP QD
 LQ73:   CONSTANT = 0.365        ! length half PEP QD
 LQ43:   CONSTANT = 0.215        ! length half PEP LER QD
 DQQ:    drift, L = LQ56-LQ43

 !arc quads
 QD    : QUADRUPO,  L=2*LQ56, K1=K1.QD
 QF    : QUADRUPO,  L=LQ73, K1=K1.QF
 QDpi  : QUADRUPO,  L=2*LQ56, K1=K1.QDpi
 QFpi  : QUADRUPO,  L=LQ73, K1=K1.QFpi
 QFBpi : QUADRUPO,  L=LQ73, K1=K1.QFBpi
 QFB   : QUADRUPO,  L=LQ73, K1=K1.QFB

 ! dispersion suppressor quads 
 QFpis : QUADRUPO,  L=LQ73, K1=K1.QFpis
 QDpis : QUADRUPO,  L=2*LQ56,K1=K1.QDpis


 ! sexts
 
 LSXT  = 0.125    ! length half-sextupole

SF1 : SEXTUPOLE, L=2*LSXT, K2 = KSF1
SF2 : SEXTUPOLE, L=LSXT, K2 = KSF2
SD1 : SEXTUPOLE, L=2*LSXT, K2 = KSD1

! D sextupoles in the dispersion suppressor
SD0I : SEXTUPOLE, L=2*LSXT, K2 = KSD0I
SD0R : SEXTUPOLE, L=2*LSXT, K2 = KSD0R
SD2I : SEXTUPOLE, L=2*LSXT, K2 = KSD2I
SD2R : SEXTUPOLE, L=2*LSXT, K2 = KSD2R

 !-----------------------------------------
 ! arc cells              
 !-----------------------------------------
FL1=1.15
  DSF:  DRIFT, L=0.25*FL1
  DSD:  DRIFT, L=0.25*FL1
  DLA2: DRIFT, L= 1.94*FL1
  DLA2pi: DRIFT, L= 2.94*FL1

  DLA2s: DRIFT, L= 2.44*FL1

  DLB: DRIFT, L=0.2*FL1
  DLBB: DRIFT, L=LBB*FL1

 LBF=1.75
 LBD=1.35
  DLBF: DRIFT, L=LBF*FL1
  DLBD: DRIFT, L=LBD*FL1

 CX_CELL_HER   : LINE=(SF2,DLB,QF, DLB, dsf, DLA2, SD1, DLB,&
                           QD, DLBD, BB, DLBF, QFB,&
                           QFB, DLBF, BB, DLBD,QD,&
                           DLB, SD1, DLA2, dsf, DLB, QF,DLB,SF2)

 CXpi_CELL_HER   : LINE=(SF2,DLB,QFpi, DLB, dsf, DLA2pi, SD1, DLB,&
                         QDpi, DLB, DLBB, BBpi, DLBB, DLB, QFBpi,&
                         QFBpi, DLB, DLBB, BBpi, DLBB, DLB, QDpi,&
                         DLB, SD1, DLA2pi, dsf, DLB, QFpi,DLB,SF2)

 CXpih_CELL_HER   : LINE=(SF2,DLB,QFpi, DLB, dsf, DLA2pi, SD1, DLB,&
                         QDpi, DLB, DLBB, BBpi, DLBB, DLB, QFBpi)

 DISP_SUPI    : LINE = (QFBpi, DLB, DLBB, BBpi, DLBB, DLB, QDpi,   &
                       DLB, SD1, DLA2pi, dsf, DLB, QFpis,DLB,SF2,&
                       SF2,DLB,QFpis,DLB, dSF, DLA2s, SD0I, DLB, QDpis, &
                       DLB, DLBB, BBs, DLBB, MBSUP)
 DISP_SUPR    : LINE = (QFBpi, DLB, DLBB, BBpi, DLBB, DLB, QDpi,   &
                       DLB, SD1, DLA2pi, dsf, DLB, QFpis,DLB,SF2,&
                       SF2,DLB,QFpis,DLB, dSF, DLA2s, SD0R, DLB, QDpis, &
                       DLB, DLBB, BBs, DLBB, MBSUP)

DISP_SUP2I    : LINE = (QFBpi, DLB, DLBB, BBpi, DLBB, DLB, QDpi,   &
                       DLB, SD1, DLA2pi, dsf, DLB, QFpis2,DLB,SF2,&
                       SF2,DLB,QFpis2,DLB, dSF, DLA2s, SD2I, DLB, QDpis2, &
                       DLB, DLBB, BBs, DLBB, MBSUP)
DISP_SUP2R    : LINE = (QFBpi, DLB, DLBB, BBpi, DLBB, DLB, QDpi,   &
                       DLB, SD1, DLA2pi, dsf, DLB, QFpis2,DLB,SF2,&
                       SF2,DLB,QFpis2,DLB, dSF, DLA2s, SD2R, DLB, QDpis2, &
                       DLB, DLBB, BBs, DLBB, MBSUP)


 !-----------------------------------------
 ! Straight disp suppr    
 !-----------------------------------------

DLMS2: DRIFT, L=0.2
DLMS3: DRIFT, L=3.0
DRFCA: drift, l=3.5

 QFMS10: QUADRUPOLE, L=2*LQ43, K1= K1.QFMS10
 QDMS10: QUADRUPOLE, L=2*LQ43, K1= K1.QDMS10
 QFMS20: QUADRUPOLE, L=2*LQ43, K1= K1.QFMS20
 QDMS20: QUADRUPOLE, L=LQ43, K1= K1.QDMS20

  SUP0I   : LINE = (MSUP0,DISP_SUPI,&
                 DLMS2,5*DQQ,QFMS10,DQQ, DLMS3, DQQ,QDMS10, DQQ,&
                   DRFCA, DQQ,QFMS20,DQQ,DRFCA, DQQ,QDMS20,5*Dqq)
  SUP0R   : LINE = (MSUP0,DISP_SUPR,&
                 DLMS2,5*DQQ,QFMS10,DQQ, DLMS3, DQQ,QDMS10, DQQ,&
                   DRFCA, DQQ,QFMS20,DQQ,DRFCA, DQQ,QDMS20,5*Dqq)


 ! straight matching quads 
 QFMS12: QUADRUPOLE, L=2*LQ43, K1= K1.QFMS12
 QDMS12: QUADRUPOLE, L=2*LQ43, K1= K1.QDMS12
 QFMS22: QUADRUPOLE, L=2*LQ43, K1= K1.QFMS22
 QDMS22: QUADRUPOLE, L=LQ43, K1= K1.QDMS22
! QFMS32: QUADRUPOLE, L=LQ43, K1= K1.QFMS32
! QDMS32: QUADRUPOLE, L=2*LQ43, K1= K1.QDMS32


 ! dispersion suppressor quads 
 QFpis2 : QUADRUPO,  L=LQ73, K1=K1.QFpis2
 QDpis2 : QUADRUPO,  L=2*LQ56,K1=K1.QDpis2

DRFCB: drift, l=2.0
DLMS33: DRIFT, L=1.5


SUP2I    : LINE = (DISP_SUP2I,&
                 DLMS2,DQQ,5*DQQ,QFMS12,DQQ, DLMS33, DQQ,QDMS12, DQQ,&
                 DRFCB, DQQ,QFMS22,DQQ,DRFCB,DQQ,QDMS22)
SUP2R    : LINE = (DISP_SUP2R,&
                 DLMS2,DQQ,5*DQQ,QFMS12,DQQ, DLMS33, DQQ,QDMS12, DQQ,&
                 DRFCB, DQQ,QFMS22,DQQ,DRFCB,DQQ,QDMS22)

!----------------------------------------------------
! arc
!----------------------------------------------------


  arc2:LINE=( -CXpih_CELL_HER, &
                 13*(CX_CELL_HER, CXPI_CELL_HER), &
                     CX_CELL_HER, CXpih_CELL_HER)

!----------------------------------------------------
! basic arc cells

CXPI_CX :    LINE=(CXPI_CELL_HER, CX_CELL_HER)
  

! ------------------------------------------------------------------------------
! End   New SuperB-like arc cells matching to DCO straights

! ==============================================================================


!--------1---------2---------3---------4---------5---------6---------7---------8
! RING
!--------1---------2---------3---------4---------5---------6---------7---------8

  MRK1:   MARKER
  MRK2:   MARKER
  MRK3:   MARKER
  MRK4:   MARKER
  MRK5:   MARKER
  MRK6:   MARKER
  MRK7:   MARKER

  IMRK1:   MARKER
  IMRK2:   MARKER
  IMRK3:   MARKER
  IMRK4:   MARKER
  IMRK5:   MARKER
  IMRK6:   MARKER
  IMRK7:   MARKER

  STRS1:   MARKER
  STRS2:   MARKER
  STRS3:   MARKER

  MRK21:   MARKER
  MRK31:   MARKER
  MRK32:   MARKER
  MRK33:   MARKER
  MRK34:   MARKER

  IMRK11:   MARKER
  IMRK12:   MARKER
  IMRK22:   MARKER
  IMRK31:   MARKER
  IMRK32:   MARKER
  IMRK33:   MARKER
  IMRK34:   MARKER
 


   STRSECR:  LINE=(   MRK1, SUP0R, MRK2,                  &
                      PHTR, MRK21, MPR, STRS3, 2*RFC,     &
                      HRFC2, MRK3, 2*RFCV, MRK31, HRFC1,  &
                      MRC, MRK32,                         &
                      MDW, MRK33, 6*WGC_OFF,              &
                   13*WGC, MRK34, -SUP2R, MRK4)


  STRSECI:  LINE=(     IMRK1,  SUP0I, IMRK11,           &
                       PHTI, IMRK12, MPI,               &
                IMRK2, INJ, IMRK22, EXT, IMRK3, MIF,    &
                IMRK31, MFC, IMRK32,   &
                IMRK33,   MDW,IMRK34, -SUP2I, IMRK4)

         
 COLLxy: RCOLLIMATOR,XSIZE=0.06,YSIZE=0.06

  HRINGR:  LINE=(    MRK1, COLLxy, SUP0R,                        &
                     PHTR, COLLxy, MRK21, MPR, STRS3, 2*RFC,     &
                     collxy,HRFC2, MRK3, 2*RFCV, MRK31, HRFC1,   &
                     MRC, MRK32, collxy,MRK33,MDW, 6*WGC_OFF     &                                        
                  collxy, 13*WGC,  -SUP2R, MRK4,                 &
                     COLLxy, ARC2)


  HRINGI:  LINE=(    IMRK1, COLLxy, SUP0I,          &
                     PHTI, COLLxy, MPI,             &
              IMRK2, INJ, EXT, IMRK3, MIF,          &
                     MFC, MDW,                      &
                     -SUP2I, IMRK4,                 &
                     COLLxy, ARC2) 

!  Complete Ring (begins from dispersion suppressor SUP0R of  STRSECR)

  RINGRI:   LINE=( HRINGR, HRINGI )

  

!----- RINGI begins from the center of INJ/EXTR section ------------------------------
 
  RINGI:  LINE=(    EXT, COLLxy, IMRK3, MIF, &
                     MFC, MDW, collxy,       &
                    -SUP2I, IMRK4,            &
                    COLLxy, ARC2,            &
                    HRINGR, COLLxy,          & 
                    IMRK1, SUP0I,             &
                    PHTI, COLLxy, MPI, collxy, &
                    IMRK2, INJ, collxy)
! ------------------------------------------------------------------------------                 

RETURN